12 DBMS_ADVISOR

DBMS_ADVISORの使用方法

この項では、DBMS_ADVISORパッケージの使用に関連する項目について説明します。

• セキュリティ・モデル

---

セキュリティ・モデル

このパッケージのセキュリティは、選択したユーザーまたはロールにこのパッケージのEXECUTE権限を付与することで制御できます。 このパッケージの先頭部分に、使用するアラート名を制限するためのカバー・パッケージを記述することもできます。 この場合は、パッケージではなく、このカバー・パッケージのEXECUTE権限を付与できます。 さらに、DBMS_ADVISORプロシージャに必要なADVISOR権限もあります。

DBMS_ADVISORサブプログラムの要約

---

ADD_SQLWKLD_REFプロシージャ

このプロシージャは、現行のSQLアクセス・アドバイザ・タスクとSQLワークロード・オブジェクト間のリンクを確立します。 このリンクを使用して、アドバイザ・タスクが分析の実行に関心のあるデータにアクセスできます。 さらに、このリンクからデータの安定したビューも得られます。 SQLアクセス・アドバイザ・タスクとSQLワークロード・オブジェクト間のリンクが確立されると、ワークロードは削除や変更から保護されます。

構文

DBMS_ADVISOR.ADD_SQLWKLD_REF (
   task_name              IN VARCHAR2,
   workload_name          IN VARCHAR2);

パラメータ

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_REF(task_name, workload_name);
END;
/

---

ADD_SQLWKLD_STATEMENTプロシージャ

このプロシージャは、指定したワークロードに単一の文を追加します。

構文

DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT (
   workload_name          IN VARCHAR2,
   module                 IN VARCHAR2,
   action                 IN VARCHAR2,
   cpu_time               IN NUMBER := 0,
   elapsed_time           IN NUMBER := 0,
   disk_reads             IN NUMBER := 0,
   buffer_gets            IN NUMBER := 0,
   rows_processed         IN NUMBER := 0,
   optimizer_cost         IN NUMBER := 0,
   executions             IN NUMBER := 1,
   priority               IN NUMBER := 2,
   last_execution_date    IN DATE := 'SYSDATE',
   stat_period            IN NUMBER := 0,
   username               IN VARCHAR2,
   sql_text               IN CLOB);

パラメータ

使用上の注意

ワークロードが現在アクティブなタスクによって参照されている場合は、変更または削除できません。 タスクは初期状態にない場合にアクティブであるとみなされます。 タスクを初期状態に設定する手順については、「RESET_TASKプロシージャ」を参照してください。

ADD_SQLWKLD_STATEMENTプロシージャは、コール元によって無視される可能性があるパラメータを複数受け入れます。実際の分析時には、cpu_time、elapsed_time、disk_reads、buffer_getsおよびoptimizer_costのみがワークロード・データのソートに使用されます。このため、実際の値は、タスク・パラメータorder_listによって特定の統計が参照される場合にのみ必要となります。新しいSQL文をワークロードに追加する場合に提供される統計を判別するには、タスク・パラメータorder_listを調べるか、または設定します。 order_listパラメータは、buffer_gets、optimizer_cost、cpu_time、disk_reads、elapsed_time、executionsおよびpriorityキーの任意の組合せを受け入れます。 priorityとoptimizer_costの一般的な設定では、SQLアクセス・アドバイザによって、priorityおよびoptimizer_costでワークロード・データがソートされ、最も高いコストの文が最初に処理されます。 ワークロードに追加する文には、適切なpriorityおよびoptimizer_costの値を含める必要があります。 他のすべての統計は、デフォルト値または0（ゼロ）に設定できます。order_listタスク・パラメータによって参照される統計キーの場合、実際のパラメータ値はワークロードの他の文と比較されるため、適切に指定する必要があります。 コール元で値を推定できない場合は、ワークロードの他の文と比較して重要度を決定できる値を選択します。 たとえば、現行の文が業務で最も重要な問合せであるとみなされる場合、適切な値は、ワークロード内の同じ統計の他のすべての値より大きい値になります。

例

DECLARE
  workload_name VARCHAR2(30);
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold) FROM sh.sales');
END;
/

---

CANCEL_TASKプロシージャ

このプロシージャは、現在実行中の処理を終了します。 このコールはソフト割込みを実行します。 Ctrl-Cなどのハード割込みのように、低レベル・データベース・アクセス・コールには割り込みません。 SQLアクセス・アドバイザは定期的にソフト割込みをチェックし、それに応じて適切に動作します。 結果として、この処理ではコールに応答するまで数秒かかることがあります。

構文

DBMS_ADVISOR.CANCEL_TASK (
   task_name      IN  VARCHAR2);

パラメータ

使用上の注意

取消しコマンドは、取り消した操作の開始前の状態にタスクを事実上復元します。 そのため、取り消されたタスクまたはデータ・オブジェクトは再開できません。

すべてのアドバイザ・タスク・プロシージャは同期されるため、操作を取り消すには、個別のデータベース・セッションを使用する必要があります。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CANCEL_TASK('My Task');
END;
/

---

CREATE_FILEプロシージャ

このプロシージャは、PL/SQL CLOB変数から外部ファイルを作成し、スクリプトやレポートの作成に使用できます。 CREATE_FILEはCLOB入力パラメータを受け入れ、指定されたファイルに文字列の内容を書き込みます。

構文

DBMS_ADVISOR.CREATE_FILE (
   buffer       IN  CLOB,
   location     IN  VARCHAR2,
   filename     IN  VARCHAR2);

パラメータ

使用上の注意

すべての書式設定をCLOBに埋め込む必要があります。

Oracleサーバーでは、ファイル・アクセスをOracleストアド・プロシージャ内に限定しています。 このため、ファイルの場所と名前は、サーバーの既知のファイル・アクセス権を厳守する必要があります。

例

CREATE DIRECTORY MY_DIR as '/homedir/user4/gssmith';
GRANT READ,WRITE ON DIRECTORY MY_DIR TO PUBLIC;

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_REF(task_name, workload_name);
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales');
  DBMS_ADVISOR.EXECUTE_TASK(task_name);
  DBMS_ADVISOR.CREATE_FILE(DBMS_ADVISOR.GET_TASK_SCRIPT(task_name),
    'MY_DIR','script.sql');

END;
/

---

CREATE_OBJECTプロシージャ

このプロシージャは、新しいタスク・オブジェクトを作成します。

構文

DBMS_ADVISOR.CREATE_OBJECT (
   task_name         IN VARCHAR2,
   object_type       IN VARCHAR2,
   attr1             IN VARCHAR2 :=  NULL,
   attr2             IN VARCHAR2 :=  NULL,
   attr3             IN VARCHAR2 :=  NULL,
   attr4             IN CLOB     :=  NULL,
   object_id         OUT NUMBER);

DBMS_ADVISOR.CREATE_OBJECT (
   task_name         IN VARCHAR2,
   object_type       IN VARCHAR2,
   attr1             IN VARCHAR2 :=  NULL,
   attr2             IN VARCHAR2 :=  NULL,
   attr3             IN VARCHAR2 :=  NULL,
   attr4             IN CLOB     :=  NULL,
   attr5             IN VARCHAR2 :=  NULL,
   object_id         OUT NUMBER);

パラメータ

属性パラメータは、オブジェクト・タイプによって値が異なります。 これらのパラメータおよびオブジェクト・タイプの詳細は、『Oracle Database管理者ガイド』を参照してください。

戻り値

新しいオブジェクト識別子を戻します。

使用上の注意

タスク・オブジェクトは、一般に、特定のアドバイザの入力データとして使用します。 セグメント・アドバイスは、オブジェクト、セグメントまたは表領域レベルで生成できます。 オブジェクト・レベルの場合、アドバイスはオブジェクトのすべてのパーティションに関して生成されます（オブジェクトがパーティション化されている場合）。 アドバイスは依存オブジェクトに伝達されません。 セグメント・レベルの場合、アドバイスは表のパーティションまたはサブパーティション、索引、LOB列などの単一のセグメントに関して取得できます。 表領域レベルの場合、表領域内のすべてのセグメントに対するターゲット・アドバイスが生成されます。

セグメント・アドバイザの詳細は、『Oracle Database管理者ガイド』を参照してください。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  obj_id NUMBER;
BEGIN
  task_name := 'My Task';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_OBJECT (task_name,'SQL',NULL,NULL,NULL,
                              'SELECT * FROM SH.SALES',obj_id);
END;
/

---

CREATE_SQLWKLDプロシージャ

このプロシージャは、ユーザーの新しいプライベートSQLワークロード・オブジェクトを作成します。 SQLワークロード・オブジェクトは、SQLアクセス・アドバイザにかわってSQLワークロードを管理します。 SQLワークロード・オブジェクトは、SQL文のインポートや更新などの他のSQLワークロード操作を実行する前に存在している必要があります。

構文

DBMS_ADVISOR.CREATE_SQLWKLD (
   workload_name            IN OUT VARCHAR2,
   description              IN VARCHAR2 := NULL,
   template                 IN VARCHAR2 := NULL,
   is_template              IN VARCHAR2 := 'FALSE');

パラメータ

戻り値

SQLアクセス・アドバイザは、新しいSQLワークロード・オブジェクト内の後続のアクティビティで使用する必要がある、一意のワークロード・オブジェクト識別子番号を戻します。

使用上の注意

デフォルトでは、組込みのデフォルト設定を使用してワークロード・オブジェクトが作成されます。 既存のワークロードのパラメータ設定またはワークロード・テンプレートを使用してワークロードを作成するには、既存のワークロード名を指定します。

SQLワークロード・オブジェクトが存在すれば、ADD_SQLWKLD_REFプロシージャを使用して、1つ以上のSQLアクセス・アドバイザのタスクから参照できます。

例

DECLARE
  workload_name VARCHAR2(30);
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
END;
/

---

CREATE_TASKプロシージャ

このプロシージャは、リポジトリ内に新しいアドバイザ・タスクを作成します。

構文

DBMS_ADVISOR.CREATE_TASK (
   advisor_name          IN VARCHAR2,
   task_id               OUT NUMBER,
   task_name             IN OUT VARCHAR2,
   task_desc             IN VARCHAR2 := NULL,
   template              IN VARCHAR2 := NULL,
   is_template           IN VARCHAR2 := 'FALSE',
   how_created           IN VARCHAR2 := NULL);

DBMS_ADVISOR.CREATE_TASK (
   advisor_name          IN VARCHAR2,
   task_name             IN VARCHAR2,
   task_desc             IN VARCHAR2 := NULL,
   template              IN VARCHAR2 := NULL,
   is_template           IN VARCHAR2 := 'FALSE',
   how_created           IN VARCHAR2 := NULL);

パラメータ

戻り値

パラメータが指定されていない場合は、一意のタスクID番号および一意のタスク名を戻します。

使用上の注意

タスクはアドバイザに関連付ける必要があり、タスクを作成すると、元のアドバイザに永久に関連付けられます。 デフォルトでは、組込みのデフォルト設定を使用してタスクが作成されます。 既存のタスクのパラメータ設定またはタスク・テンプレートを使用してワークロードを作成するには、既存のタスク名を指定します。

SQLアクセス・アドバイザの場合、advisor_nameとして識別子DBMS_ADVISOR.SQLACCESS_ADVISORを使用します。

SQLアクセス・アドバイザは、次の定数を使用して、3つの組込みのタスク・テンプレートを提供します。

• DBMS_ADVISOR.SQLACCESS_OLTP

  パラメータはOLTPアプリケーション環境向けにプリセットされます。

• DBMS_ADVISOR.SQLACCESS_WAREHOUSE

  パラメータはデータ・ウェアハウス・アプリケーション環境向けにプリセットされます。

• DBMS_ADVISOR.SQLACCESS_GENERAL

  パラメータは、OLTPとデータ・ウェアハウスの両方の操作が行われる可能性のあるハイブリッド・アプリケーション環境向けにプリセットされます。 SQLアクセス・アドバイザの場合、これがデフォルトのテンプレートです。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';
  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
END;
/

---

DELETE_SQLWKLDプロシージャ

このプロシージャは、リポジトリから既存のSQLワークロードを削除します。

構文

DBMS_ADVISOR.DELETE_SQLWKLD (
   workload_name        IN VARCHAR2);

パラメータ

使用上の注意

ワークロードが現在アクティブなタスクによって参照されている場合は、変更または削除できません。 タスクは初期状態にない場合にアクティブであるとみなされます。 タスクを初期状態に設定するには、「RESET_TASKプロシージャ」を参照してください。

例

DECLARE
  workload_name VARCHAR2(30);
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.DELETE_SQLWKLD(workload_name);
END;
/

---

DELETE_SQLWKLD_REFプロシージャ

このプロシージャは、現行のSQLアクセス・アドバイザのタスクとSQLワークロード・データ・オブジェクト間のリンクを削除します。

構文

DBMS_ADVISOR.DELETE_SQLWKLD_REF (
   task_name              IN VARCHAR2,
   workload_name          IN NUMBER);

パラメータ

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_REF(task_name, workload_name);
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales');
  DBMS_ADVISOR.DELETE_SQLWKLD_REF(task_name, workload_name);
END;
/

---

DELETE_SQLWKLD_STATEMENTプロシージャ

このプロシージャは、ワークロードから1つ以上の文を削除します。

構文

DBMS_ADVISOR.DELETE_SQLWKLD_STATEMENT (
   workload_name        IN VARCHAR2,
   sql_id               IN NUMBER);

DBMS_ADVISOR.DELETE_SQLWKLD_STATEMENT (
   workload_name        IN VARCHAR2,
   search               IN VARCHAR2,
   deleted              OUT NUMBER);

パラメータ

使用上の注意

ワークロードが現在アクティブなタスクによって参照されている場合は、変更または削除できません。 タスクは初期状態にない場合にアクティブであるとみなされます。 タスクを初期状態に設定するには、「RESET_TASKプロシージャ」を参照してください。

例

DECLARE
  workload_name VARCHAR2(30);
  deleted NUMBER;
  id NUMBER;
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'YEARLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales');

   SELECT sql_id INTO id FROM USER_ADVISOR_SQLW_STMTS
   WHERE workload_name = 'My Workload';

  DBMS_ADVISOR.DELETE_SQLWKLD_STATEMENT(workload_name, id);
END;
/

---

DELETE_TASKプロシージャ

このプロシージャは、リポジトリから既存のタスクを削除します。

構文

DBMS_ADVISOR.DELETE_TASK (
   task_name          IN VARCHAR2);

パラメータ

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.DELETE_TASK(task_name);
END;
/

---

EXECUTE_TASKプロシージャ

このプロシージャは、アドバイザ分析、または指定したタスクの評価を行います。

構文

DBMS_ADVISOR.EXECUTE_TASK (
   task_name          IN VARCHAR2);

パラメータ

使用上の注意

タスクの実行は同期処理です。 処理が完了するか、またはユーザーの割込みが検出されるまで、コントロールはコール元に返されません。

コントロールが返されると、DBA_ADVISOR_LOG表で実行状態をチェックできます。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_REF(task_name, workload_name);
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales');
  DBMS_ADVISOR.EXECUTE_TASK(task_name);
END;
/

---

GET_REC_ATTRIBUTESプロシージャ

このプロシージャは、アドバイザ分析による推奨のとおりに、新しいオブジェクトの指定した属性を取得します。

構文

DBMS_ADVISOR.GET_REC_ATTRIBUTES (
   workload_name         IN VARCHAR2,
   rec_id                IN NUMBER,
   action_id             IN NUMBER,
   attribute_name        IN VARCHAR2,
   value                 OUT VARCHAR2,
   owner_name            IN VARCHAR2 := NULL);

パラメータ

戻り値

要求された属性値はVALUE引数に戻されます。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
  attribute VARCHAR2(100);
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';
  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_REF(task_name, workload_name);
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales WHERE promo_id = 10');
  DBMS_ADVISOR.EXECUTE_TASK(task_name);
  DBMS_ADVISOR.GET_REC_ATTRIBUTES(task_name, 1, 1, 'NAME', attribute);
END;
/

---

GET_TASK_REPORTファンクション

このファンクションは、指定したタスクのレポートを作成して戻します。

構文

DBMS_ADVISOR.GET_TASK_REPORT (
   task_name      IN VARCHAR2,
   type           IN VARCHAR2 := 'TEXT',
   level          IN VARCHAR2 := 'TYPICAL',
   section        IN VARCHAR2 := 'ALL',
   owner_name     IN VARCHAR2 := NULL)
RETURN CLOB;

パラメータ

戻り値

スクリプトを受け取るバッファを戻します。

---

GET_TASK_SCRIPTファンクション

このファンクションは、SQL*Plus互換SQLスクリプトを作成し、ファイルに出力します。 このスクリプトには、指定したタスクから受け入れるすべてのリコメンデーションを格納します。

構文

DBMS_ADVISOR.GET_TASK_SCRIPT (
   task_name          IN VARCHAR2
   type               IN VARCHAR2 := 'IMPLEMENTATION',
   rec_id             IN NUMBER := NULL,
   act_id             IN NUMBER := NULL,
   owner_name         IN VARCHAR2 := NULL)
RETURN CLOB;

パラメータ

戻り値

CLOBバッファとしてスクリプトを戻します。

使用上の注意

スクリプトは実行する準備ができていますが、新しいマテリアライズド・ビューおよび索引の受け入れ可能な場所についてスクリプトを確認することをお薦めします。

生成されたスクリプトに含まれるリコメンデーションは、受入れ済としてマークする必要があります。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
  buf CLOB;
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_REF(task_name, workload_name);
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales');
  DBMS_ADVISOR.EXECUTE_TASK(task_name);
    buf := DBMS_ADVISOR.GET_TASK_SCRIPT(task_name);
END;
/

---

IMPLEMENT_TASKプロシージャ

指定したタスクのリコメンデーションを実装します。

構文

DBMS_ADVISOR.IMPLEMENT_TASK (
   task_name          IN VARCHAR2,
   rec_id             IN NUMBER := NULL,
   exit_on_error      IN BOOLEAN := NULL);

パラメータ

---

IMPORT_SQLWKLD_SCHEMAプロシージャ

このプロシージャは、スキーマに基づいたSQLワークロードを構築し、ロードします。 このワークロードは仮定ワークロードとも呼ばれます。

構文

DBMS_ADVISOR.IMPORT_SQLWKLD_SCHEMA (
   workload_name         IN VARCHAR2,
   import_mode           IN VARCHAR2 := 'NEW',
   priority              IN NUMBER := 2,
   saved_rows            OUT NUMBER,
   failed_rows           OUT NUMBER);

パラメータ

戻り値

このコールでは、保存された行数と失敗した行数が出力パラメータとして戻されます。

使用上の注意

仮定ワークロードを正しくインポートするには、ターゲット・スキーマにディメンションが格納されている必要があります。

VALID_TABLE_LISTパラメータを設定しない場合、検索領域が著しく大きくなり、実行に長い時間を要することがあります。 検索領域を特定の一連の表に制限することをお薦めします。

タスクに以前の実行からの有効なリコメンデーションが含まれる場合に、タスクを追加または変更すると、そのタスクが無効としてマークされ、価値の高いリコメンデーション・データの表示とレポートが妨げられることがあります。

例

DECLARE
  workload_name VARCHAR2(30);
  saved NUMBER;
  failed NUMBER;
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.SET_SQLWKLD_PARAMETER(workload_name,'VALID_TABLE_LIST','SH.%');
  DBMS_ADVISOR.IMPORT_SQLWKLD_SCHEMA(workload_name, 'REPLACE', 1, saved,
     failed);
END;
/

---

IMPORT_SQLWKLD_SQLCACHEプロシージャ

このプロシージャは、サーバーのSQLキャッシュの現行の内容からSQLワークロードを作成します。

構文

DBMS_ADVISOR.IMPORT_SQLWKLD_SQLCACHE (
   workload_name         IN VARCHAR2,
   import_mode           IN VARCHAR2 := 'NEW',
   priority              IN NUMBER := 2,
   saved_rows            OUT NUMBER,
   failed_rows           OUT NUMBER);

パラメータ

戻り値

このコールでは、保存された行数と失敗した行数が出力パラメータとして戻されます。

使用上の注意

ワークロードが現在アクティブなタスクによって参照されている場合は、変更または削除できません。 タスクは初期状態にない場合にアクティブであるとみなされます。 タスクを初期状態に設定するには、「RESET_TASKプロシージャ」を参照してください。

例

DECLARE
  workload_name VARCHAR2(30);
  saved NUMBER;
  failed NUMBER;
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.SET_SQLWKLD_PARAMETER(workload_name,'VALID_TABLE_LIST','SH.%');
  DBMS_ADVISOR.IMPORT_SQLWKLD_SQLCACHE(workload_name, 'REPLACE', 1, saved,
     failed);
END;
/

---

IMPORT_SQLWKLD_STSプロシージャ

このプロシージャは、既存のSQLチューニング・セットからSQLワークロードをロードします。 SQLチューニング・セットは、一般に、様々な時刻と日付フィルタを使用してサーバー・ワークロード・リポジトリから作成されます。

構文

DBMS_ADVISOR.IMPORT_SQLWKLD_STS (
   workload_name         IN VARCHAR2,
   sts_name              IN VARCHAR2,
   import_mode           IN VARCHAR2 := 'NEW',
   priority              IN NUMBER := 2,
   saved_rows            OUT NUMBER,
   failed_rows           OUT NUMBER);

DBMS_ADVISOR.IMPORT_SQLWKLD_STS (
   workload_name         IN VARCHAR2,
   sts_owner             IN VARCHAR2,
   sts_name              IN VARCHAR2,
   import_mode           IN VARCHAR2 := 'NEW',
   priority              IN NUMBER := 2,
   saved_rows            OUT NUMBER,
   failed_rows           OUT NUMBER);

パラメータ

戻り値

このコールでは、保存された行数と失敗した行数が出力パラメータとして戻されます。

使用上の注意

ワークロードが現在アクティブなタスクによって参照されている場合は、変更または削除できません。 タスクは初期状態にない場合にアクティブであるとみなされます。 タスクを初期状態に設定するには、「RESET_TASKプロシージャ」を参照してください。

例

DECLARE
  workload_name VARCHAR2(30);
  saved NUMBER;
  failed NUMBER;
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.SET_SQLWKLD_PARAMETER(workload_name,'VALID_TABLE_LIST','SH.%');
  DBMS_ADVISOR.IMPORT_SQLWKLD_STS(workload_name, 'MY_SQLSET', 'REPLACE', 1,
     saved, failed);
END;
/

---

IMPORT_SQLWKLD_SUMADVプロシージャ

このプロシージャは、サマリー・アドバイザ・ワークロードからSQLワークロードを収集します。 このプロシージャの目的は、SQLアクセス・アドバイザへのOracle9i データベースのサマリー・アドバイザ・ユーザーの移行を支援することです。

構文

DBMS_ADVISOR.IMPORT_SQLWKLD_SUMADV (
   workload_name         IN VARCHAR2,
   import_mode           IN VARCHAR2 := 'NEW',
   priority              IN NUMBER := 2,
   sumadv_id             IN NUMBER,
   saved_rows            OUT NUMBER,
   failed_rows           OUT NUMBER);

パラメータ

戻り値

このコールでは、保存された行数と失敗した行数が出力パラメータとして戻されます。

使用上の注意

ワークロードが現在アクティブなタスクによって参照されている場合は、変更または削除できません。 タスクは初期状態にない場合にアクティブであるとみなされます。 タスクを初期状態に設定するには、「RESET_TASKプロシージャ」を参照してください。

例

DECLARE
  workload_name VARCHAR2(30);
  saved NUMBER;
  failed NUMBER;
  sumadv_id NUMBER;
BEGIN
  workload_name := 'My Workload';
  sumadv_id := 394;

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.SET_SQLWKLD_PARAMETER(workload_name,'VALID_TABLE_LIST','SH.%');
  DBMS_ADVISOR.IMPORT_SQLWKLD_SUMADV(workload_name, 'REPLACE', 1, sumadv_id,
    saved, failed);
END;
/

---

IMPORT_SQLWKLD_USERプロシージャ

このプロシージャは、指定したユーザー表からSQLワークロードを収集します。

構文

DBMS_ADVISOR.IMPORT_SQLWKLD_USER (
   workload_name         IN VARCHAR2,
   import_mode           IN VARCHAR2 := 'NEW',
   owner_name            IN VARCHAR2,
   table_name            IN VARCHAR2,
   saved_rows            OUT NUMBER,
   failed_rows           OUT NUMBER);

パラメータ

戻り値

このコールでは、保存された行数と失敗した行数が出力パラメータとして戻されます。

使用上の注意

ワークロードが現在アクティブなタスクによって参照されている場合は、変更または削除できません。 タスクは初期状態にない場合にアクティブであるとみなされます。 タスクを初期状態に設定するには、「RESET_TASKプロシージャ」を参照してください。

例

DECLARE
  workload_name VARCHAR2(30);
  saved NUMBER;
  failed NUMBER;
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.SET_SQLWKLD_PARAMETER(workload_name,'VALID_TABLE_LIST','SH.%');
  DBMS_ADVISOR.IMPORT_SQLWKLD_USER(workload_name, 'REPLACE', 'SH',
    'USER_WORKLOAD', saved, failed);
END;
/

---

INTERRUPT_TASKプロシージャ

このプロシージャは、現在実行中のタスクを停止します。 タスクは、正常終了時と同じように処理を停止します。 ユーザーは、この時点までに存在するすべてのリコメンデーションにアクセスできます。

構文

DBMS_ADVISOR.INTERRUPT_TASK (
   task_name          IN VARCHAR2);

パラメータ

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.EXECUTE_TASK(task_name);
END;
/

このセッションがタスクを実行中に、次の文を使用して2番目のセッションからタスクを中断できます。

BEGIN
  DBMS_ADVISOR.INTERRUPT_TASK('My Task');
END;
/

---

MARK_RECOMMENDATIONプロシージャ

このプロシージャは、インポートまたは実装用にリコメンデーションをマークします。

構文

DBMS_ADVISOR.MARK_RECOMMENDATION (
   task_name          IN VARCHAR2
   id                 IN NUMBER,
   action             IN VARCHAR2);

パラメータ

使用上の注意

リコメンデーションを実装する場合は、受入れ済としてマークされている必要があります。 デフォルトでは、すべてのリコメンデーションが受入れ済としてみなされ、生成されるすべてのスクリプトに表示されます。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
  attribute VARCHAR2(100);
  rec_id NUMBER;
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_REF(task_name, workload_name);
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales WHERE promo_id = 10');
  DBMS_ADVISOR.EXECUTE_TASK(task_name);

  rec_id := 1;
  DBMS_ADVISOR.MARK_RECOMMENDATION(task_name, rec_id, 'REJECT');
END;
/

---

QUICK_TUNEプロシージャ

このプロシージャは、分析を実行し、単一のSQL文のリコメンデーションを生成します。

これにより、指定したSQL文の分析に必要なすべての処理を短縮できます。 この操作によって、指定したタスク名を使用したタスクが作成されます。 このタスクは、指定したアドバイザ・タスク・テンプレートを使用して作成されます。 最終的に、タスクが実行され、結果がリポジトリに保存されます。

構文

DBMS_ADVISOR.QUICK_TUNE (
   advisor_name           IN VARCHAR2,
   task_name              IN VARCHAR2,
   attr1                  IN CLOB,
   attr2                  IN VARCHAR2 := NULL,
   attr3                  IN NUMBER := NULL,
   task_or_template       IN VARCHAR2 := NULL);

パラメータ

使用上の注意

ユーザーが指定する場合は、最終的なリコメンデーションをプロシージャによって実装できます。

タスクは指定したSQLアクセス・アドバイザのタスク・テンプレートまたは組込みのデフォルトのSQLACCESS_GENERALテンプレートのいずれかを使用して作成されます。 ワークロードには指定した文のみが格納され、すべてのタスク・パラメータはデフォルトに設定されます。

attr1はチューニングする単一のSQL文にする必要があります。 SQLアクセス・アドバイザの場合、attr2は単一の文を実行するユーザーになります。 省略した場合は現行のユーザーが使用されます。

例

DECLARE
  task_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';

  DBMS_ADVISOR.QUICK_TUNE(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_name,
                  'SELECT AVG(amount_sold) FROM sh.sales WHERE promo_id=10');
END;
/

---

RESET_SQLWKLDプロシージャ

このプロシージャは、ワークロードを初期開始ポイントにリセットします。 これにより、すべてのジャーナル・メッセージ、ログ・メッセージが削除され、必要な変動および利用統計情報が再計算されます。

構文

DBMS_ADVISOR.RESET_SQLWKLD (
   workload_name        IN VARCHAR2);

パラメータ

使用上の注意

RESET_SQLWKLDは、SQL文の追加や削除などのワークロードを調整してから実行する必要があります。

例

DECLARE
  workload_name VARCHAR2(30);
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales WHERE promo_id = 10');

  DBMS_ADVISOR.RESET_SQLWKLD(workload_name);
END;
/

---

RESET_TASKプロシージャ

このプロシージャは、タスクを初期状態にリセットします。 タスクから、すべての中間データおよびリコメンデーション・データが削除されます。 タスクの状態はINITIALに設定されます。

構文

DBMS_ADVISOR.RESET_TASK (
   task_name          IN VARCHAR2);

パラメータ

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_REF(task_name, workload_name);
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales WHERE promo_id = 10');
  DBMS_ADVISOR.EXECUTE_TASK(task_name);

  DBMS_ADVISOR.RESET_TASK(task_name);
END;
/

---

SET_DEFAULT_SQLWKLD_PARAMETERプロシージャ

このプロシージャは、SQLワークロード・オブジェクトまたはSQLワークロード・オブジェクト・テンプレート内のユーザー・パラメータのデフォルト値を変更します。 ユーザー・パラメータは、ワークロード・コレクション、チューニングの決定およびレポートに影響を及ぼす様々な属性を格納する単一の変数です。 パラメータのデフォルト値を変更すると、ワークロード・オブジェクトの作成時に新しい値が継承されます。

構文

DBMS_ADVISOR.SET_DEFAULT_SQLWKLD_PARAMETER (
   parameter            IN VARCHAR2,
   value                IN VARCHAR2);

DBMS_ADVISOR.SET_DEFAULT_SQLWKLD_PARAMETER (
   parameter            IN VARCHAR2,
   value                IN NUMBER);

パラメータ

使用上の注意

パラメータが影響を及ぼすのは、ワークロード・コレクションを変更する操作に限られます。 そのため、新しいSQL文をワークロードにインポートまたは追加する前にパラメータを設定する必要があります。 データをワークロードに配置した後にパラメータを設定しても、既存のデータに影響を与えません。

例

BEGIN
  DBMS_ADVISOR.SET_DEFAULT_SQLWKLD_PARAMETER('VALID_TABLE_LIST','SH.%');
END;
/

---

SET_DEFAULT_TASK_PARAMETERプロシージャ

このプロシージャは、タスクまたはテンプレート内のユーザー・パラメータのデフォルト値を変更します。 ユーザー・パラメータは、アドバイザの操作に様々な影響を与える、様々な属性を格納する単一の変数です。 パラメータのデフォルト値を変更すると、タスクの作成時に新しい値が継承されます。

デフォルトのタスクは、通常のタスクとは異なります。 デフォルト値は、新しく作成したタスクに挿入される初期値ですが、SET_TASK_PARAMETERを指定してタスク・パラメータを設定すると、ローカル値のみが設定されます。 したがって、SET_DEFAULT_TASK_PARAMETERは、既存のタスクに影響を与えません。

構文

DBMS_ADVISOR.SET_DEFAULT_TASK_PARAMETER (
   advisor_name        IN VARCHAR2
   parameter           IN VARCHAR2,
   value               IN VARCHAR2);

DBMS_ADVISOR.SET_DEFAULT_TASK_PARAMETER (
   advisor_name        IN VARCHAR2
   parameter           IN VARCHAR2,
   value               IN NUMBER);

パラメータ

例

BEGIN
  DBMS_ADVISOR.SET_DEFAULT_TASK_PARAMETER(DBMS_ADVISOR.SQLACCESS_ADVISOR,
   'VALID_TABLE_LIST', 'SH.%');
END;
/

---

SET_SQLWKLD_PARAMETERプロシージャ

このプロシージャは、SQLワークロード・オブジェクトまたはSQLワークロード・オブジェクト・テンプレート内のユーザー・パラメータを変更します。 ユーザー・パラメータは、ワークロード・コレクション、チューニングの決定およびレポートに影響を及ぼす様々な属性を格納する単一の変数です。

構文

DBMS_ADVISOR.SET_SQLWKLD_PARAMETER (
   workload_name        IN VARCHAR2,
   parameter            IN VARCHAR2,
   value                IN VARCHAR2);

DBMS_ADVISOR.SET_SQLWKLD_PARAMETER (
   workload_name        IN VARCHAR2,
   parameter            IN VARCHAR2,
   value                IN NUMBER);

パラメータ

使用上の注意

パラメータが影響を及ぼすのは、ワークロード・コレクションを変更する操作に限られます。 そのため、新しいSQL文をワークロードにインポートまたは追加する前にパラメータを設定する必要があります。 データをワークロードに配置した後にパラメータを設定しても、既存のデータに影響を与えません。

SQLワークロード・オブジェクトのパラメータ

表12-31に、SQLアクセス・アドバイザのオブジェクト・パラメータを示します。

例

DECLARE
  workload_name VARCHAR2(30);
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.SET_SQLWKLD_PARAMETER(workload_name, 'VALID_TABLE_LIST','SH.%');
END;
/

---

SET_TASK_PARAMETERプロシージャ

このプロシージャは、アドバイザ・タスクまたはテンプレート内のユーザー・パラメータを変更します。 ユーザー・パラメータは、ワークロード・コレクション、チューニングの決定およびレポートに影響を及ぼす様々な属性を格納する単一の変数です。

構文

DBMS_ADVISOR.SET_TASK_PARAMETER (
   task_name           IN VARCHAR2
   parameter           IN VARCHAR2,
   value               IN VARCHAR2);

DBMS_ADVISOR.SET_TASK_PARAMETER (
   task_name           IN VARCHAR2
   parameter           IN VARCHAR2,
   value               IN NUMBER);

パラメータ

使用上の注意

タスクは、初期状態にある場合を除いて変更できません。 タスクを初期状態に設定するには、「RESET_TASKプロシージャ」を参照してください。 このプロシージャの使用方法の詳細は、アドバイザ固有のマニュアルを参照してください。

SQLアクセス・アドバイザのタスク・パラメータ

表12-33に、SQLアクセス・アドバイザのタスク・パラメータを示します。

セグメント・アドバイザのパラメータ

表12-34に、セグメント・アドバイザでSET_TASK_PARAMETERプロシージャを使用して設定できる入力タスク・パラメータを示します。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';

   DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
   DBMS_ADVISOR.SET_TASK_PARAMETER(task_name, 'VALID_TABLELIST',
      'SH.%,SCOTT.EMP');
END;
/

UNDOアドバイザのタスク・パラメータ

表12-35に、UNDOアドバイザでSET_TASK_PARAMETERプロシージャを使用して設定できる入力タスク・パラメータを示します。

例

DECLARE
   tname  VARCHAR2(30);
   oid    NUMBER;
   BEGIN
     DBMS_ADVISOR.CREATE_TASK('Undo Advisor', tid, tname, 'Undo Advisor Task');
     DBMS_ADVISOR.CREATE_OBJECT(tname, 'UNDO_TBS', null, null, null, 'null', oid);
     DBMS_ADVISOR.SET_TASK_PARAMETER(tname, 'TARGET_OBJECTS', oid);
     DBMS_ADVISOR.SET_TASK_PARAMETER(tname, 'START_SNAPSHOT', 1);
     DBMS_ADVISOR.SET_TASK_PARAMETER(tname, 'END_SNAPSHOT', 2);
     DBMS_ADVISOR.EXECUTE_TASK(tname);
   END;
/

自動データベース診断モニター（ADDM）のタスク・パラメータ

表12-36に、ADDMでSET_TASK_PARAMETERプロシージャを使用して設定できる入力タスク・パラメータを示します。

例

DECLARE
   tid     NUMBER;
BEGIN
   DBMS_ADVISOR.CREATE_TASK('ADDM', tid, 'ADDM_TEST', 'my test');
   DBMS_ADVISOR.SET_TASK_PARAMETER('ADDM_TEST', 'START_SNAPSHOT', '19',
                                             -  'END_SNAPSHOT',   '26',
                                             -  'DB_ID', '155789304',
                                             -  'INSTANCE', '1');
   DBMS_ADVISOR.EXECUTE_TASK('ADDM_TEST');
END;
/

SQLチューニング・アドバイザのタスク・パラメータ

詳細は、DBMS_SQLTUNEパッケージおよび『Oracle Databaseパフォーマンス・チューニング・ガイド』を参照してください。

---

TUNE_MVIEWプロシージャ

このプロシージャは、マテリアライズド・ビューを複数のマテリアライズド・ビューに分解する方法、またはリフレッシュおよびクエリー・リライトの高速化を優先してマテリアライズド・ビューを更新する方法を示します。 さらに、マテリアライズド・ビュー・ログを修正する方法やクエリー・リライトを有効にする方法も示します。

構文

DBMS_ADVISOR.TUNE_MVIEW (
   task_name IN OUT VARCHAR2,
   mv_create_stmt IN [CLOB | VARCHAR2]);

パラメータ

使用上の注意

TUNE_MVIEWを実行すると、2つの一連の出力結果が生成されます。一方はCREATE実装に対するもので、もう一方はCREATE MATERIALIZED VIEW実装の取消しに対するものです。 出力結果はUSER_TUNE_MVIEWビューおよびDBA_TUNE_MVIEWビューからアクセスできます。 さらに、DBMS_ADVISOR.GET_TASK_SCRIPTおよびDBMS_ADVISOR.CREATE_FILEを使用して、TUNE_MVIEW結果をスクリプト・ファイルに出力し、後で実行できます。

USER_TUNE_MVIEWビューとDBA_TUNE_MVIEWビュー

これらのビューは、TUNE_MVIEWプロシージャの実行後に結果を取得します。

例

name VARCHAR2(30);
DBMS_ADVISOR.TUNE_MVIEW.(name, 'SELECT AVG(C1) FROM my_fact_table WHERE c10 = 7');

次の例に、TUNE_MVIEWを使用して、CREATE MATERIALIZED VIEW文を最適化する方法を示します。

NAME VARCHAR2(30) := 'my_tune_mview_task';
EXECUTE DBMS_ADVISOR.TUNE_MVIEW (name, 'CREATE MATERIALIZED VIEW MY_MV
REFRESH FAST AS SELECT C2, AVG(C1) FROM MY_FACT_TABLE WHERE C10 = 7
GROUP BY C2');

次の例のように、USER_TUNE_MVIEWまたはDBA_TUNE_MVIEWを問い合せてCREATE出力結果を表示できます。

SELECT * FROM USER_TUNE_MVIEW WHERE TASK_NAME='my_tune_mview_task' AND
SCRIPT_TYPE='CREATE';

または、次の例のように、出力結果を外部スクリプト・ファイルに保存することもできます。

CREATE DIRECTORY TUNE_RESULTS AS  ''/myscript_dir'' ;
GRANT READ, WRITE ON DIRECTORY TUNE_RESULTS TO PUBLIC;
EXECUTE DBMS_ADVISOR.CREATE_FILE(DBMS_ADVISOR.GET_TASK_SCRIPT('my_tune_mview_task'), -
'/homes/tune','my_tune_mview_create.sql');

前述の文によって、CREATE出力結果が/myscript_dir/my_tune_mview_create.sqlに保存されます。

---

UPDATE_OBJECTプロシージャ

このプロシージャは、既存のタスク・オブジェクトを更新します。 タスク・オブジェクトは、一般に、特定のアドバイザの入力データとして使用します。 セグメント・アドバイスは、オブジェクト、セグメントまたは表領域レベルで生成できます。

構文

DBMS_ADVISOR.UPDATE_OBJECT (
   task_name       IN VARCHAR2
   object_id       IN NUMBER,
   attr1           IN VARCHAR2 := NULL,
   attr2           IN VARCHAR2 := NULL,
   attr3           IN VARCHAR2 := NULL,
   attr4           IN CLOB := NULL,
   attr5           IN VARCHAR2 := NULL);

パラメータ

属性パラメータは、オブジェクト・タイプによって値が異なります。 これらのパラメータおよびオブジェクト・タイプの詳細は、『Oracle Database管理者ガイド』を参照してください。

使用上の注意

オブジェクト・レベルの場合、アドバイスはオブジェクトのすべてのパーティションに関して生成されます（オブジェクトがパーティション化されている場合）。 アドバイスは依存オブジェクトに伝達されません。 セグメント・レベルの場合、アドバイスは表のパーティションまたはサブパーティション、索引、LOB列などの単一のセグメントに関して取得できます。 表領域レベルの場合、表領域内のすべてのセグメントに対するターゲット・アドバイスが生成されます。

セグメント・アドバイザの詳細は、『Oracle Database管理者ガイド』を参照してください。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  obj_id NUMBER;
BEGIN
  task_name := 'My Task';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_OBJECT (task_name,'SQL',NULL,NULL,NULL,
                              'SELECT * FROM SH.SALES',obj_id);
  DBMS_ADVISOR.UPDATE_OBJECT (task_name, obj_id,NULL,NULL,NULL,
                              'SELECT count(*) FROM SH.SALES');
END;
/

---

UPDATE_REC_ATTRIBUTESプロシージャ

このプロシージャは、リコメンデーションの所有者、名前および表領域を更新します。

構文

DBMS_ADVISOR.UPDATE_REC_ATTRIBUTES (
   task_name            IN VARCHAR2
   rec_id               IN NUMBER,
   action_id            IN NUMBER,
   attribute_name       IN VARCHAR2,
   value                IN VARCHAR2);

パラメータ

使用上の注意

タスクが正しく実行されないかぎり、リコメンデーション属性は変更できません。

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
  workload_name VARCHAR2(30);
  attribute VARCHAR2(100);
BEGIN
  task_name := 'My Task';
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_REF(task_name, workload_name);
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales WHERE promo_id = 10');
  DBMS_ADVISOR.EXECUTE_TASK(task_name);

attribute := 'SH';

  DBMS_ADVISOR.UPDATE_REC_ATTRIBUTES(task_name, 1, 3, 'OWNER', attribute);
END;
/

---

UPDATE_SQLWKLD_ATTRIBUTESプロシージャ

このプロシージャは、SQLワークロード・オブジェクトまたはテンプレートの様々な属性を変更します。

構文

DBMS_ADVISOR.UPDATE_SQLWKLD_ATTRIBUTES (
   workload_name        IN VARCHAR2,
   new_name             IN VARCHAR2 := NULL,
   description          IN VARCHAR2 := NULL,
   read_only            IN VARCHAR2 := NULL,
   is_template          IN VARCHAR2 := NULL,
   how_created          IN VARCHAR2 := NULL);

パラメータ

例

DECLARE
  workload_name VARCHAR2(30);
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales WHERE promo_id = 10');
  DBMS_ADVISOR.UPDATE_SQLWKLD_ATTRIBUTES(workload_name,'New workload name');
END;
/

---

UPDATE_SQLWKLD_STATEMENTプロシージャ

このプロシージャは、指定したSQLワークロード内の既存のSQL文を更新します。

構文

DBMS_ADVISOR.UPDATE_SQLWKLD_STATEMENT (
   workload_name     IN VARCHAR2,
   sql_id            IN NUMBER,
   application       IN VARCHAR2 := NULL,
   action            IN VARCHAR2 := NULL,
   priority          IN NUMBER := NULL,
   username          IN VARCHAR2 := NULL);

DBMS_ADVISOR.UPDATE_SQLWKLD_STATEMENT (
   workload_name     IN VARCHAR2,
   search            IN VARCHAR2,
   updated           OUT NUMBER,
   application       IN VARCHAR2 := NULL,
   action            IN VARCHAR2 := NULL,
   priority          IN NUMBER := NULL,
   username          IN VARCHAR2 := NULL);

パラメータ

使用上の注意

ワークロードが現在アクティブなタスクによって参照されている場合は、変更または削除できません。 タスクは初期状態にない場合にアクティブであるとみなされます。 タスクを初期状態に設定するには、「RESET_TASKプロシージャ」を参照してください。

例

DECLARE
  workload_name VARCHAR2(30);
  updated NUMBER;
  id NUMBER;
BEGIN
  workload_name := 'My Workload';

  DBMS_ADVISOR.CREATE_SQLWKLD(workload_name, 'My Workload');
  DBMS_ADVISOR.ADD_SQLWKLD_STATEMENT(workload_name, 'MONTHLY', 'ROLLUP',
                                     100,400,5041,103,640445,680000,2,
                                     1,SYSDATE,1,'SH','SELECT AVG(amount_sold)
                                     FROM sh.sales WHERE promo_id = 10');

   SELECT sql_id INTO id FROM USER_ADVISOR_SQLW_STMTS
   WHERE workload_name = 'My Workload';

  DBMS_ADVISOR.UPDATE_SQLWKLD_STATEMENT(workload_name, id);
END;
/

---

UPDATE_TASK_ATTRIBUTESプロシージャ

このプロシージャは、タスクまたはタスク・テンプレートの様々な属性を変更します。

構文

DBMS_ADVISOR.UPDATE_TASK_ATTRIBUTES (
   task_name          IN VARCHAR2
   new_name           IN VARCHAR2 := NULL,
   description        IN VARCHAR2 := NULL,
   read_only          IN VARCHAR2 := NULL,
   is_template        IN VARCHAR2 := NULL,
   how_created        IN VARCHAR2 := NULL);

パラメータ

例

DECLARE
  task_id NUMBER;
  task_name VARCHAR2(30);
BEGIN
  task_name := 'My Task';

  DBMS_ADVISOR.CREATE_TASK(DBMS_ADVISOR.SQLACCESS_ADVISOR, task_id, task_name);
  DBMS_ADVISOR.UPDATE_TASK_ATTRIBUTES(task_name,'New Task Name');
  DBMS_ADVISOR.UPDATE_TASK_ATTRIBUTES('New Task Name',NULL,'New description');
END;
/